と、いうわけで、FDのブートセクタを逆アセンブル・解析してみました。
って解析したのは去年の7月だったんだけど・・・更新ネタがちょっと尽きてきたかな・・・
んで。
ぱっとみてわかるのは、86系の比較的初期の命令しかつかって無いと言うところです。
掛け算すらないし、そもそも16bitコードです。
基本的に除算もないのですが、なぜか1箇所だけあったり。
余りが6バイトしかないからなぁ・・・
起動時はFDの先頭セクタ512バイトを0000:7C00-7DFFに読みこみ、7C00からスタートします。
全体の目的は、ルートディレクトリ中のIO.SYSというファイルを読みこみ、実行する事です。
最初に512バイトのおおよその概要を書いておきます。
0000 - 003D BPB部分
003E - 0045 スタックポインタ初期化
0046 - 0082 FDドライブのパラメータ保存、FDドライブ初期化 → 終了後00A3へ飛ぶ
0083 - 008B エラー時処理："I/O error."を表示して009Eの再起動ルーチンへ
008C - 0092 エラー時処理："No system."を表示して続く再起動ルーチンへ
0093 - 00AD 再起動処理："Hit any key."を表示して再起動
00AE - 00DC FAT領域の読み込み
00DD - 00F5 ルートディレクトリからIO.SYSのあるクラスタを探索
00F6 - 012F クラスタ番号からセクタ番号への変換
0130 - 0169 IO.SYSのうち３セクタを読み込み、そこへジャンプ → あとはIO.SYSの制御へ
以下はサブルーチン
016A - 0177 [DS:SI]の文字列を表示
0179 - 0183 [ES:BX]にdl(7C24hの中身)から1セクタ読みこみ
0184 - 01B9 CHS形式−[7C50]/[7C52]/[7C54]の値を調整する
01BA - 01C6 CHS形式−[7C50]/[7C52]/[7C54]の値をint 13hで利用するレジスタに読みこみ
01C7 - 01D1 文字列："IO SYS"
01D2 - 01DE 文字列："\nNo System."
01DF - 01EB 文字列："\nI/O error."
01EC - 01F9 文字列："Hit any key."
01FA - 01FD 未使用４バイト
01FE - 01FF ブートセクタであることを示す55AAの定数
|
メモリの使い方。
間にOSが入っているわけでもないので、通りすぎたコード領域をそのまま変数用メモリとして使っているようですね。
0078 -- 後で7C42を代入する
007A -- 後で0000を代入する
7C3E -- 起動時の0078hの中身を保存
7C40 -- 起動時の007Ahの中身を保存
7C42--7C4D -- 0078hの示すアドレスから11byte分コピーする
7C44 -- トラックあたりヘッダ数
7C49 -- 0Fh
7C4C -- 予約セクタ+FAT数*FATセクタ(==ルート)
7C4E -- 予約セクタ+FAT数*FATセクタ
7C50 -- 0
7C52 -- 0
7C54 -- 1
|
開始からFDドライブの初期化まで
で、こっからがコード。
左側の
:0000
は実際には7C00だけずれてます。
:0000 EB3C jmp 003E
:0002 90 nop
:0003 2A 5F 2D 4B 3E 49 48 43 00 02 01 01 00 02 E0 00
40 0B F0 09 00 12 00 02 00 00 00 00 00 00 00 00
00 00 00 29 00 00 00 00 4E 4F 20 4E 41 4D 45 20
20 20 20 46 41 54 31 32 20 20 20 //BPB領域
|
ここまでは前回の戯れ言で出てきたBPBデータ。
最初のjmp命令でデータ部は読み飛ばされます。
以後変数の処理が続くようですね。
:003E FA cli //割りこみ不可
:003F 33C0 xor ax, ax //ax=0
:0041 8EC0 mov es, ax //es=ax
:0043 8ED0 mov ss, ax //ss=ax
:0045 8D26007C lea sp, [7C00] //sp=7c00h
|
スタックポインタを初期化しています。
:0049 BF7800 mov di, 0078 //di=78h
:004C 26C535 lds si, es:[di] //si=*(0078h) ds=*(007Ah)
:004F 89363E7C mov [7C3E], si //*(7C3Eh) = si
:0053 8C1E407C mov [7C40], ds //*(7C40h) = ds
:0057 FC cld //ループフラグクリア DF=0 inc
:0058 BF427C mov di, 7C42 //di=7C42h
:005B B90B00 mov cx, 000B //cx=0Bh
:005E F3 repz //cx=0の間リピート
:005F A4 movsb //[DS:SI]→[ES:DI] 11バイト
|
0078や007Aの内容を一端7C3Eと7C40に退避させていますね。
SIレジスタは0078の内容が入っているので、そこから11バイトDI=7C42にコピー。
:0060 8ED8 mov ds, ax //ds=ax
:0062 C606497C0F mov byte ptr [7C49], 0F //*(7C49h)=0Fh
:0067 8A0E187C mov cl , [7C18] //cl=*(7C18h) トラックあたりヘッダ数
:006B 880E447C mov [7C44], cl //*(7C44h)=cl
:006F C7067800427C mov word ptr [0078], 7C42 //*(0078h)=7C42h
:0075 A37A00 mov word ptr [007A], ax //*(007Ah)=ax
:0078 FB sti //割りこみ許可
|
ax=0なので最初でds=0、7C49には0Fh=15を代入していますね。
コメントにあるように7C18には1つのトラック当たりのセクタ数が入っていますが、それを7C44にコピーしています。
0078、007Aにはなんか値をいれていますが、なぜ7C42とaxなのかはわかりませんでした・・・
- (2005/12補足)---------------------------------
-
0078の番地には、割り込み番号0x1Eに対応する割り込みハンドラのアドレスが入っているはずです。
しかし、割り込みリストを見ると、0x1EはFDドライブのパラメータリストが入る領域を指しているようです。
通常0078:007AはF000:EFC7を指しており、この領域はBIOS内にあります。
このパラメータは通常11byteで出来ています。
上のプログラムではその中身11byteを一端7C42にコピーし、0078に7C42を、007Aにax(=0000)を代入しています。
これが意味するところは、
「起動時のBIOSが持つFDドライブパラメータを一端メモリ中にコピーしておき、以後FDのアクセス時にはそちらを参照させる」
と言うことです。
(2005/12補足ここまで)---------------------------------
:0079 B400 mov ah, 00 //ah=0
:007B 32D2 xor dl, dl //dl=0
:007D CD13 int 13 //int 13h(Disk Systemリセット)
:007F 7202 jb 0083 //0083h エラー時"I/O error."表示し停止
:0081 EB2B jmp 00AE //00AEh 成功時ジャンプ
|
Interrupt Jump Tableなどをみるとわかりますが、ah=0でのint 13hの割りこみは「RESET DISK SYSTEM」だそうです。
FDドライブの初期化かな？
失敗するとCFフラグが立つので、jbで以後0083以降のエラー処理に飛びます。
成功時はエラー処理を通過して00AEまでジャンプします。
エラー処理＆再起動
//エラー時
// I/Oエラー時
* Referenced by a (U)nconditional or (C)onditional Jump at Addresses:
|:007F(C), :00DB(C), :0142(U)
|
:0083 8D36DF7D lea si, [7DDF] //si=7DDFh "I/O error."
:0087 E8E000 call 016A //016Ah呼び出し(上記文字列表示)
:008A EB07 jmp 0093 //0093hジャンプ
|
上から飛んできた場合のエラー処理ルーチンですね。
7DDFには文字列「I/O error.」が入っています。
そのまま文字列表示関数の入っている016Aを呼び出します。
(JmpとちがいCallは関数呼び出しなのであとで戻ってくる。)
016Aはsiの差すアドレスの文字列を表示する関数ですね。
それが終わると再起動ルーチン0093へ飛びます。
次のプログラムはまた別のところから呼ばれるサブルーチンです。
// OS見つからず
* Referenced by a (U)nconditional or (C)onditional Jump at Address:
|:00F4(C)
|
:008C 8D36D27D lea si, [7DD2] //si=7DD2h "No system."
:0090 E8D700 call 016A //016Ah呼び出し(上記文字列表示)
|
これは後でIO.SYSファイルが見つからない時のエラーですね。
7DD2には「No system.」という文字列が入っています。
やはり文字列表示をした後そのまま再起動ルーチンに続きます。
//エラー・OS見つからず・・・
* Referenced by a (U)nconditional or (C)onditional Jump at Address:
|:008A(U)
|
:0093 8D36EC7D lea si, [7DEC] //si=7DECh "Hit any key."
:0097 E8D000 call 016A //016Ah呼び出し(上記文字列表示)
:009A 33C0 xor ax, ax //ax=0
:009C CD16 int 16 //キー入力待ち
|
7DECの「Hit any key.」をやはり016Aで表示した後、ax=0でint 16hを呼んでいます。
これはキーボード入力用の命令ですが、キーが押されるまで制御が戻らないようですね。
:009E BF7800 mov di, 0078 //di=78h
:00A1 A13E7C mov ax, word ptr [7C3E] //ax=*(7C3E) 7C3Eから4バイトを
:00A4 8905 mov [di], ax //*(di)=*(78h)=ax 78hの指すアドレスに
:00A6 A1407C mov ax, word ptr [7C40] //ax=*(7C40) 出力(si,ds)
:00A9 894502 mov [di+02], ax //*(di+2)=*(80h)=ax 起動時に戻す
:00AC CD19 int 19 //リブート？
|
再起動ルーチンです。
:004F 89363E7C
:0053 8C1E407C
で7C3E、7C40に0078、0080の値を退避させていたため、その値を戻してint 19hを呼びます。
int 19hは「BOOTSTRAP LOADER」でブートレコードを実行するので、BIOSで設定されている次のブート用ディスクの処理に入ります。
このFDからのブートは諦めて次へ行こうと言うことですね。
FATからIO.SYSを探す
ようやくエラー処理ルーチンを抜け、int 13hが成功した時の処理です。
//成功時
* Referenced by a (U)nconditional or (C)onditional Jump at Address:
|:0081(U)
|
//各種変数初期化
:00AE A10E7C mov ax, word ptr [7C0E] //ax=*(7C0E) 予約セクタ数
:00B1 32ED xor ch, ch //ch=0
:00B3 8A0E107C mov cl, [7C10] //cl=*(7C10h) FAT数
:00B7 0306167C add ax, [7C16] //ax+=FATセクタ数
:00BB E2FA loop 00B7 //上をFAT数繰り返すことでax=予約セクタ+FAT数*FATセクタ
|
上記は予約セクタ数+FAT数*FATセクタを求めています。
乗算を使わず、あえてループして足し算をしているのは古いCPUの名残でしょうか？
予約セクタ数とFATセクタの次はルートディレクトリの内容が入っているはずですね。
:00BD A34C7C mov word ptr [7C4C], ax //*(7C4Ch) = ax
:00C0 A34E7C mov word ptr [7C4E], ax //*(7C4Eh) = ax
:00C3 33C0 xor ax, ax //ax=0
:00C5 A3507C mov word ptr [7C50], ax //*(7C50h) = ax = 0
:00C8 A3527C mov word ptr [7C52], ax //*(7C52h) = ax = 0
:00CB 40 inc ax //ax++ (0->1)
:00CC A3547C mov word ptr [7C54], ax //*(7C54h) = ax = 1
|
ここは先ほどの「予約セクタ数+FAT数*FATセクタ」他0や1をメモリに代入していますね。
:00CF E8B200 call 0184 //0184h CHS設定
:00D2 E8E500 call 01BA //01BAh CHS読みこみ
|
Cylinder,Head,Sectorの値を設定するルーチンです。
0184は適切に割り算などして、シリンダ・ヘッド・セクタ番号を範囲内に納めるルーチンです。
01BAはその値をセクタ読みこみルーチンint 13hに合うようにcxなどのレジスタに値を格納するルーチンです。
:00D5 BB0005 mov bx, 0500 //bx=500h 読みこみセクタ書きこみ先
:00D8 E89E00 call 0179 //0179h 1セクタ読みこみ
:00DB 72A6 jb 0083 //失敗したらI/O error. |
読みこんだセクタの書きこみ先を0500として、1セクタの内容を読みこむ関数0179を呼んでいます。
失敗すると先ほど出てきた「I/O error.」を表示して再起動するルーチンに進むようです。
:00DD BF0005 mov di, 0500 //di=500h
:00E0 F6450B08 test byte ptr [di+0B], 08 //*(di+0Bh) の下から4bit目チェック（ボリュームラベル？）
:00E4 7403 je 00E9 //立ってなければ00E9へ
:00E6 83C720 add di, 0020 //di+=0020 ボリュームラベルなら次のレコードへ
|
で、ルートディレクトリの先頭レコードをチェックします。
先頭レコードがボリュームラベルだったら１レコード=32byteだけポインタを進めます。
* Referenced by a (U)nconditional or (C)onditional Jump at Address:
|:00E4(C)
|
:00E9 57 push di //di保存
:00EA 8D36C77D lea si, [7DC7] //si=7DC7 "IO.SYS" --- DI=ID.SYS?
:00EE B90B00 mov cx, 000B //cx=000B
:00F1 F3 repz //
:00F2 A6 cmpsb //cx=11bitが等しいか？----------
:00F3 5F pop di //diとりだし
:00F4 7596 jne 008C //IO.SYS探索失敗→"No system." 008Ch
|
diにはルートディレクトリの先頭レコード（ボリュームラベルがあればその次）が入っていることになります。
diを使うので一端pushしておき、先頭レコードにあるファイル名がIO.SYSであるかどうかチェックします。
7DC7には「ID______SYS」と６つスペースが入っていますが、元々FAT12,16では8-3形式に合わせてスペースが充填されるのでこれで正しいです。
repz-cmpsbはcx分だけ連続するメモリ領域が等しいかどうかをチェックします。
IO.SYSがない場合は008Cの「No system.」の表示＋再起動に飛びます。
これをみると、IO.SYSがあるだけではだめで、先頭レコードにある必要があるようですね。
:00F6 268B451A mov ax, es:[di+1A] //ax=*(di+1A) 先頭クラスタ下位2バイト
:00FA 48 dec ax //
:00FB 48 dec ax //ax -= 2
|
先頭クラスタがIO.SYSであることがわかったので、実際に読みこみます。
まずIO.SYSの実際のデータが入っているクラスタからセクタを求めます。
各レコードの1Ahバイト目にクラスタ番号が入っています。
前回書いたように、クラスタ番号は002から始まるため、2を引きます。
:00FC 33DB xor bx, bx //bx=0
:00FE 32ED xor ch, ch //ch=0
:0100 8A0E0D7C mov cl , [7C0D] //cl=*(7C0Dh) セクタ/クラスタ
:0104 03D8 add bx, ax //bx += ax
:0106 E2FC loop 0104 //bx = ax*cl 何セクタ目か？
|
クラスタ当たりのセクタ数を取得します。
まぁ普通のFDDなら1なんですが。
その後、clの回数axの足し算をする事でbx=ax*clが入ります。
クラスタ番号＊（セクタ/クラスタ）なので、bxは結局セクタ番号が入ります。
:0108 011E4C7C add [7C4C], bx //*(7C4Ch) += bx ルート位置+セクタ
:010C 891E4E7C mov [7C4E], bx //*(7C4Eh) = bx セクタ
|
先ほどのセクタ番号は0からスタートするものなので、実際にはBPB、FAT、ルートディレクトリの分ずらす必要があります。
:00BD A34C7C
で7C4Cにはルートディレクトリのセクタ番号が入っているので、それに足しこみます。
7C4Eには
:0110 8B1E0B7C mov bx, [7C0B] //bx=*(7C0Bh) バイト/セクタ(512)
:0114 B105 mov cl, 05 //cl=05h
:0116 D3EB shr bx, cl //bx>>cl(bx>>5) (512/32=16)１セクタ中ファイルエントリ
|
最後にルートエントリ分を足す必要があります。
bxにセクタ当たりのバイト数(512)を読みこみ、右に5ビットシフトしています。
１レコードが32バイトなので、１セクタ当たりのレコード数を求めるんですね。
:0118 A1117C mov ax, word ptr [7C11] //ax=*(7C11h) ルートエントリ最大数
:011B F6F3 div bl //ax/bl ルートエントリは何セクタ？
:011D 0AE4 or ah, ah //ah==0
:011F 7402 je 0123 //ax mod bl=0 then 0123h
:0121 FEC0 inc al //al++ セクタ数余りなら繰り上げ
|
１セクタ当たりのレコード数が求まったので、次にルートディレクトリのセクタ数を求めます。
axにルートレコードのレコード数が求まるので、それを１セクタ当たりのレコード数で割ります。
割り切れない場合、div blの余りがahに入るので、ahが0かどうかをチェックし、0でなければ
商alを繰り上げます。
これでalにルートディレクトリのセクタ数が入ったことになります。
* Referenced by a (U)nconditional or (C)onditional Jump at Address:
|:011F(C)
|
:0123 32E4 xor ah, ah //ah=0
:0125 01064C7C add [7C4C], ax //*(7C4Ch) += ax ルートエントリ分追加
:0129 01064E7C add [7C4E], ax //*(7C4Eh) += ax ルートエントリ分追加
:012D E85400 call 0184 //現在ルートエントリを指すCHSにルート分追加
:0130 B90300 mov cx, 0003 //cx=3
:0133 BB0007 mov bx, 0700 //bx=700h
|
ah=0は前のdiv blで値が変更されてしまったのを戻すためでしょう。
ルートエントリ分を7C4C,7C4Eに足し、0184を呼び出して適切なCHSを設定します。
bx=0700はIO.SYSの読みこみ先です。
//３セクタI/O sysから呼び出し
* Referenced by a (U)nconditional or (C)onditional Jump at Address:
|:0155(U)
|
:0136 51 push cx //cx,bxの保存
:0137 53 push bx //
:0138 E87F00 call 01BA //7C50,7C52,7C54の値を読みこむ
:013B E83B00 call 0179 //1セクタbxに読みこみ
:013E 5B pop bx //bx=700hに復帰
:013F 59 pop cx //cx=3に復帰
:0140 7303 jnb 0145 //エラーなし
:0142 E93EFF jmp 0083 //エラー時0083h
|
01BAと0179でIO.SYSの内容をbx=700へ読みこみます。
エラーがなければ0145へ続きますが、エラーがあると0083の「I/O error.」表示＋再起動へ飛びます。
* Referenced by a (U)nconditional or (C)onditional Jump at Address:
|:0140(C)
|
:0145 49 dec cx //cx--
:0146 740F je 0157 //cx==0 0157h
:0148 C7064E7C0100 mov word ptr [7C4E], 0001 //*(7C4E)=1
:014E E83300 call 0184 //0184 (1セクタずつすすめる)
:0151 031E0B7C add bx, [7C0B] //bx+=*(7C0Bh) (512バイト/セクタ)
:0155 EBDF jmp 0136 //0136h
|
ここに入る段階ではcx=3なのでいきなりje 0157にはひっかかりませんね。
セクタ番号を1進め、読みこみ先を512バイト進めていることから、IO.SYSを3セクタ分読みこみたいようです。
* Referenced by a (U)nconditional or (C)onditional Jump at Address:
|:0146(C)
|
:0157 8A2E157C mov ch, [7C15] //ch=*(7C15) //メディアタイプディスクリプタ
:015B 8A16247C mov dl, [7C24] //dl=*(7C24h) //ドライブ番号
:015F 8B1E4C7C mov bx, [7C4C] //bx=*(7C4C) //IO.SYSの実行部セクタ番号
:0163 33C0 xor ax, ax //ax=0
:0165 EA00007000 jmp 0070:0000 //IO.SYSの来るアドレス
|
あとはIO.SYSのアドレスへ制御を移します。
必要なデータをレジスタに入れ、IO.SYSに飛びます。
(2005/12修正)
IO.SYSは0700に書き込んだので、そこからプログラムの実行を行うため、0070:0000にジャンプします。
これで全体の流れは終了です。
あとはまた小さな関数がいくつか入っています。
//[DS:SI]以下の文字列をNULL文字に至るまで表示
* Referenced by a CALL at Addresses:
|:0087, :0090, :0097
|
* Referenced by a (U)nconditional or (C)onditional Jump at Address:
|:0177(U)
|
:016A AC lodsb //al=[DS:SI] , SI++
:016B 0AC0 or al , al //al != 0 ?
:016D 7501 jne 0170 //al>0なら0170
:016F C3 ret //それ以外はリターン
|
これは文字列表示の関数です。
SIに表示したい文字列のアドレスが渡されますね。
lodsbは[DS:SI]の中身をalに読みこみつつ、SIをインクリメントする命令です。
al=*(si++)と思えばいいでしょうか。
読みこんだ値が0であればorの値が0になりますが、それ以外の場合は1文字表示するルーチンの0170に飛びます。
0まで来たら関数を抜けます。
* Referenced by a (U)nconditional or (C)onditional Jump at Address:
|:016D(C)
|
:0170 BB0700 mov bx, 0007 //bx=0007h
:0173 B40E mov ah, 0E //ah=0Eh
:0175 CD10 int 10 //alの文字を白色で出力
:0177 EBF1 jmp 016A //016Ahへ戻る
|
上から続く1文字表示の関数です。int 10hは画面制御の命令が色々入っています。
ah=0Eの時は「TELETYPE OUTPUT」が呼ばれます。
blで表示の色を指定できますが、ここでは07で白色ですね。
VBでいうQBColor関数と同じ色指定の仕方と同じです。
1文字表示すると再び1文字読みこみに016Aへ戻ります。
//1セクタ読みこみルーチン
* Referenced by a CALL at Addresses:
|:00D8, :013B
|
:0179 B402 mov ah, 02 //ah=02
:017B B001 mov al, 01 //al=01
:017D 8A16247C mov dl, [7C24] //dl=*(7C24)
:0181 CD13 int 13 //[ES:BX]にdlから１セクタ読みこみ
:0183 C3 ret
|
7C24の差すセクタ番号から1セクタ読みこみ、bxのさすアドレスに格納します。
ah=02の時のint 13hは「READ SECTOR(S) INTO MEMORY」で名前の通りです。
読みこむセクタ数はal=1、ドライブ番号は7C24になります。
関数01BAでシリンダ・ヘッド・セクタ番号(CHS)は既に各レジスタに
//チェックルーチン？
//[7C50] -- ヘッダ番号
//[7C52] -- トラック番号
//[7C54]+[7C4E] -- セクタ番号
//ヘッダ・トラック・セクタ番号を所定の範囲内の数値に押さえる
//[7C50]/[7C52]/[7C54]に書きこむ
* Referenced by a CALL at Addresses:
|:00CF, :012D, :014E
|
:0184 8B3E507C mov di, [7C50] //di=*(7C50h)
:0188 8B36527C mov si, [7C52] //si=*(7C52h)
:018C A1547C mov ax, word ptr [7C54] //ax=*(7C54h)
:018F 03064E7C add ax, [7C4E] //ax += *(7C4E)
:0193 EB05 jmp 019A
//ax=ルート位置+1
//di=si=0
|
適切なCHS値を設定するルーチンです。
全体のセクタをリニアに扱いたいところですが、int 13hではCHSの3値でセクタを扱う必要があります。
そこで、割り算などをして範囲内に納めます。
元々C=[7C52]、H=[7C50]、S=[7C54]に納まっている値に[7C4E]セクタだけ進めた値を取得します。
si=C、di=H、ax=Sが入っている状態になります。
その後019A以降の割り算ルーチンへ飛びます。
* Referenced by a (U)nconditional or (C)onditional Jump at Address:
|:019E(C)
|
:0195 2B06187C sub ax, [7C18] //ax -= *(7C18h)
:0199 46 inc si //si++
* Referenced by a (U)nconditional or (C)onditional Jump at Address:
|:0193(U)
|
:019A 3B06187C cmp ax, [7C18] //ax <> *(7C18h) （トラックあたりセクタ数）
:019E 77F5 ja 0195 //ax > *(7C18h)なら 0195h
//si=セクタ番号/トラックあたりセクタ数 = トラック番号
//ax=セクタ番号modトラックあたりセクタ数 = トラック内セクタ
|
上からは019Aに飛んできますね。
S=axが[7C18]=トラック当たりセクタ数より大きい限り0195に飛びます。
0195ではaxをトラック当たりセクタ数引いてその分トラック数を1増やしてます。
要はトラック当たりセクタ数より大きい分だけヘッダ番号に繰り上げをしてるんですね。
:01A0 A3547C mov word ptr [7C54], ax //*(7C54) = ax
:01A3 8BC6 mov ax, si //ax = si
:01A5 EB05 jmp 01AC //01ACh
|
この時点ではセクタ番号は確定なので[7C54]に戻しています。
//[7C54]にトラック内セクタ番号
//ax=トラック番号
* Referenced by a (U)nconditional or (C)onditional Jump at Address:
|:01B0(C)
|
:01A7 2B061A7C sub ax, [7C1A] //ax -= *(7C1A) （ドライブヘッド数）
:01AB 47 inc di //di++
* Referenced by a (U)nconditional or (C)onditional Jump at Address:
|:01A5(U)
|
:01AC 3B061A7C cmp ax, [7C1A] //ax <> *(7C1A) （ドライブヘッド数）
:01B0 73F5 jnb 01A7 //ax>=*(7C1A)なら01A7hへ
//di=トラック番号/ヘッドあたりドライブ数 = ヘッダ番号
//ax=トラック番号modヘッドあたりドライブ数 = ヘッダ内トラック番号
|
今度は同様にヘッドの値を繰上げしてシリンダの値を増やしています。
:01B2 A3527C mov word ptr [7C52], ax //*(7C52) = ax
:01B5 893E507C mov [7C50], di //*(7C50) = di
:01B9 C3 ret
|
終わったら[7C52]と[7C50]を設定し、関数を抜けます。
ここで設定した値は後で01BAで呼び出されます。
//7C50,7C52,7C54の値を読みこむ(int13h呼び出し用)
//[7C50]/[7C52]/[7C54] = ch/dh/cl
* Referenced by a CALL at Addresses:
|:00D2, :0138
|
:01BA 8A2E507C mov ch, [7C50] //ch=*(7C50)
:01BE 8A36527C mov dh, [7C52] //dh=*(7C52)
:01C2 8A0E547C mov cl, [7C54] //cl=*(7C54)
:01C6 C3 ret
|
シリンダ・ヘッド・セクタ番号を適切にレジスタにセットするルーチンです。
この関数を読んだ後0179が呼ばれますね。
:01C7 49 4F 20 20 20 20 20 20 53 59 53 "ID SYS"
:01D2 0D 0A 4E 6F 20 73 79 73 74 65 6D 2E 00 "\nNo System.\0"
:01DF 0D 0A 49 2F 4F 20 65 72 72 6F 72 2E 00 "\nI/O error.\0"
:01EC 20 48 69 74 20 61 6E 79 20 6B 65 79 2E 00 "Hit any key.\0"
:01FA 00 00 00 00
:01FE 55 push bp
:01FF AA stosb
|
あとは文字列データ。最後の55AAは何だかわかりませんが、残りはたったの6バイト！
これはあんまり凝った事はできないな・・・
|
以上で終了です。
HDDの場合は、パーティションテーブルを読みこんで、アクティブなパーティションの先頭セクタに制御を移すコードが入ります。
色々やってますが、結局IO.SYSを読みこむだけ(^^;)
次回はようやくアセンブラでコードを書こうかと思います。
と言ってもファイルシステムがどうとかマルチスレッドがとか簡単にできるわけがないので、BIOSの命令を使って簡単なプログラムを作ってみたいと思います。
単なるプログラムではOSとは言えないので、intの割りこみ命令を定義する予定です。
|
